Distorted Android

//////////////////////////////////////////////////////////////////////////////////////////////

// Copyright 2016 Leszek Koltunski                                                          //

//                                                                                          //

// This file is part of Distorted.                                                          //

//                                                                                          //

// Distorted is free software: you can redistribute it and/or modify                        //

// it under the terms of the GNU General Public License as published by                     //

// the Free Software Foundation, either version 2 of the License, or                        //

// (at your option) any later version.                                                      //

//                                                                                          //

// Distorted is distributed in the hope that it will be useful,                             //

// but WITHOUT ANY WARRANTY; without even the implied warranty of                           //

// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the                            //

// GNU General Public License for more details.                                             //

//                                                                                          //

// You should have received a copy of the GNU General Public License                        // 

// along with Distorted.  If not, see <http://www.gnu.org/licenses/>.                       //

//////////////////////////////////////////////////////////////////////////////////////////////

precision highp float;

precision highp int;

in vec3 a_Position;                  // Per-vertex position.

in vec3 a_Normal;                    // Per-vertex normal vector.

in vec3 a_Inflate;                   // This vector describes the direction this vertex needs to go when we 'inflate' the whole mesh.

                                     // If the mesh is locally smooth, this is equal to the normal vector. Otherwise (on sharp edges) - no.

in vec2 a_TexCoordinate;             // Per-vertex texture coordinate.

in float a_Tag;                      // Per-vertex tag. Connects the vertex (really the mesh component the vertex is a member of) to a vertex effect.

                                     // An effect will only be active on a vertex iff (a_Tag & vTag[effect]) != 0.  ( see VertexEffect.retSection() )

out vec3 v_Position;                 //

out vec3 v_endPosition;              // for Transform Feedback only

#ifdef PREAPPLY

out vec3 v_Inflate;                  // Transform Feedback for preapply effects

#endif

out vec3 v_Normal;                   //

out vec2 v_TexCoordinate;            //

uniform mat4 u_MVPMatrix;            // the combined model/view/projection matrix.

uniform mat4 u_MVMatrix;             // the combined model/view matrix.

uniform float u_Inflate;             // how much should we inflate (>0.0) or deflate (<0.0) the mesh.

#if NUM_VERTEX>0

uniform int vNumEffects;             // total number of vertex effects

uniform int vName[NUM_VERTEX];       // their names.

uniform vec4 vUniforms[3*NUM_VERTEX];// i-th effect is 3 consecutive vec4's: [3*i], [3*i+1], [3*i+2].

                                     // The first vec4 is the Interpolated values,

                                     // second vec4: first float - cache, next 3: Center, the third -  the Region.

uniform int vTag[NUM_VERTEX];        // Tags of the vertex effects. Tags are used to connect an effect to a Mesh component.

//////////////////////////////////////////////////////////////////////////////////////////////

// HELPER FUNCTIONS

//////////////////////////////////////////////////////////////////////////////////////////////

// Return degree of the point as defined by the Region. Currently only supports spherical regions.

//

// Let 'PS' be the vector from point P (the current vertex) to point S (the center of the effect).

// Let region.xyz be the vector from point S to point O (the center point of the region sphere)

// Let region.w be the radius of the region sphere.

// (This all should work regardless if S is inside or outside of the sphere).

//

// Then, the degree of a point with respect to a given (spherical!) Region is defined by:

//

// If P is outside the sphere, return 0.

// Otherwise, let X be the point where the halfline SP meets the sphere - then return |PX|/|SX|,

// aka the 'degree' of point P.

//

// We solve the triangle OPX.

// We know the lengths |PO|, |OX| and the angle OPX, because cos(OPX) = cos(180-OPS) = -cos(OPS) = -PS*PO/(|PS|*|PO|)

// then from the law of cosines PX^2 + PO^2 - 2*PX*PO*cos(OPX) = OX^2 so PX = -a + sqrt(a^2 + OX^2 - PO^2)

// where a = PS*PO/|PS| but we are really looking for d = |PX|/(|PX|+|PS|) = 1/(1+ (|PS|/|PX|) ) and

// |PX|/|PS| = -b + sqrt(b^2 + (OX^2-PO^2)/PS^2) where b=PS*PO/|PS|^2 which can be computed with only one sqrt.

float degree(in vec4 region, in vec3 PS)

  {

  vec3 PO  = PS + region.xyz;

  float D = region.w*region.w-dot(PO,PO);      // D = |OX|^2 - |PO|^2

  if( D<=0.0 ) return 0.0;

  float ps_sq = dot(PS,PS);

  float one_over_ps_sq = 1.0/(ps_sq-(sign(ps_sq)-1.0));  // return 1.0 if ps_sq = 0.0

                                                         // Important: if we want to write

                                                         // b = 1/a if a!=0, b=1 otherwise

                                                         // we need to write that as

                                                         // b = 1 / ( a-(sign(a)-1) )

                                                         // [ and NOT 1 / ( a + 1 - sign(a) ) ]

                                                         // because the latter, if 0<a<2^-24,

                                                         // will suffer from round-off error and in this case

                                                         // a + 1.0 = 1.0 !! so 1 / (a+1-sign(a)) = 1/0 !

  float DOT  = dot(PS,PO)*one_over_ps_sq;

  return 1.0 / (1.0 + 1.0/(sqrt(DOT*DOT+D*one_over_ps_sq)-DOT));

  }

#endif  // NUM_VERTEX>0

//////////////////////////////////////////////////////////////////////////////////////////////

void main()

  {

  vec3 v = a_Position + u_Inflate*a_Inflate;

  vec3 n = a_Normal;

#ifdef PREAPPLY

  vec3 inf = a_Inflate;

#endif

#if NUM_VERTEX>0

  int effect=0;

  for(int i=0; i<vNumEffects; i++)

    {

    // ENABLED EFFECTS WILL BE INSERTED HERE

    effect+=3;

    }

#endif

  v_Position      = v;

#ifdef PREAPPLY

  v_endPosition   = n;

  v_Inflate       = inf;

#else

  v_endPosition   = v + 0.5*n;

#endif

  v_TexCoordinate = a_TexCoordinate;

  v_Normal        = normalize(vec3(u_MVMatrix*vec4(n,0.0)));

  gl_Position     = u_MVPMatrix*vec4(v,1.0);

  }