Distorted Android

//////////////////////////////////////////////////////////////////////////////////////////////

// Copyright 2016 Leszek Koltunski                                                          //

//                                                                                          //

// This file is part of Distorted.                                                          //

//                                                                                          //

// Distorted is free software: you can redistribute it and/or modify                        //

// it under the terms of the GNU General Public License as published by                     //

// the Free Software Foundation, either version 2 of the License, or                        //

// (at your option) any later version.                                                      //

//                                                                                          //

// Distorted is distributed in the hope that it will be useful,                             //

// but WITHOUT ANY WARRANTY; without even the implied warranty of                           //

// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the                            //

// GNU General Public License for more details.                                             //

//                                                                                          //

// You should have received a copy of the GNU General Public License                        //

// along with Distorted.  If not, see <http://www.gnu.org/licenses/>.                       //

//////////////////////////////////////////////////////////////////////////////////////////////

precision lowp float;

#if __VERSION__ != 100

in vec2 v_TexCoordinate;

out vec4 fragColor;

#define TEXTURE texture

#define FRAG_COLOR fragColor

#else

varying vec2 v_TexCoordinate;

#define TEXTURE texture2D

#define FRAG_COLOR gl_FragColor

#endif

uniform sampler2D u_ColorTexture;

uniform sampler2D u_DepthTexture;

uniform float u_Offsets[MAX_BLUR];

uniform float u_Weights[MAX_BLUR];

uniform int u_Radius;

//////////////////////////////////////////////////////////////////////////////////////////////

void main()

  {

  float depth = TEXTURE(u_DepthTexture,v_TexCoordinate).r;

  if( u_Radius>1 )

    {

    float offset = u_Offsets[u_Radius];

    depth = min(depth, TEXTURE(u_DepthTexture,vec2(v_TexCoordinate.x,v_TexCoordinate.y+offset)).r);

    depth = min(depth, TEXTURE(u_DepthTexture,vec2(v_TexCoordinate.x,v_TexCoordinate.y-offset)).r);

    depth = min(depth, TEXTURE(u_DepthTexture,vec2(v_TexCoordinate.x+offset,v_TexCoordinate.y)).r);

    depth = min(depth, TEXTURE(u_DepthTexture,vec2(v_TexCoordinate.x-offset,v_TexCoordinate.y)).r);

    }

  gl_FragDepth = depth;

  vec4 pixel= TEXTURE(u_ColorTexture,v_TexCoordinate) * u_Weights[0];

  for (int i=1; i<=u_Radius; i+=1)

    {

    pixel += ( TEXTURE(u_ColorTexture,vec2(v_TexCoordinate.x,v_TexCoordinate.y+u_Offsets[i])) +

               TEXTURE(u_ColorTexture,vec2(v_TexCoordinate.x,v_TexCoordinate.y-u_Offsets[i])) ) * u_Weights[i];

    }

  FRAG_COLOR = pixel;

  }