Distorted Android

//////////////////////////////////////////////////////////////////////////////////////////////

// Copyright 2016 Leszek Koltunski                                                          //

//                                                                                          //

// This file is part of DistortedLibrary.                                                          //

//                                                                                          //

// DistortedLibrary is free software: you can redistribute it and/or modify                        //

// it under the terms of the GNU General Public License as published by                     //

// the Free Software Foundation, either version 2 of the License, or                        //

// (at your option) any later version.                                                      //

//                                                                                          //

// DistortedLibrary is distributed in the hope that it will be useful,                             //

// but WITHOUT ANY WARRANTY; without even the implied warranty of                           //

// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the                            //

// GNU General Public License for more details.                                             //

//                                                                                          //

// You should have received a copy of the GNU General Public License                        // 

// along with DistortedLibrary.  If not, see <http://www.gnu.org/licenses/>.                       //

//////////////////////////////////////////////////////////////////////////////////////////////

precision highp float;

precision highp int;

in vec3 a_Position;                  // Per-vertex position.

in vec3 a_Normal;                    // Per-vertex normal vector.

in vec3 a_Inflate;                   // This vector describes the direction this vertex needs to go when we 'inflate' the whole mesh.

                                     // If the mesh is locally smooth, this is equal to the normal vector. Otherwise (on sharp edges) - no.

in vec2 a_TexCoordinate;             // Per-vertex texture coordinate.

out vec3 v_Position;                 //

out vec3 v_endPosition;              // for Transform Feedback only

out vec3 v_Normal;                   //

out vec2 v_TexCoordinate;            //

uniform vec3 u_Bounding;             // MeshBase.mBounding{X,Y,Z}

uniform vec3 u_Stretch;              // MeshBase.mStretch{X,Y,Z}

uniform mat4 u_MVPMatrix;            // the combined model/view/projection matrix.

uniform mat4 u_MVMatrix;             // the combined model/view matrix.

uniform float u_Inflate;             // how much should we inflate (>0.0) or deflate (<0.0) the mesh.

#if NUM_VERTEX>0

uniform int vNumEffects;             // total number of vertex effects

uniform int vName[NUM_VERTEX];       // their names.

uniform vec4 vUniforms[3*NUM_VERTEX];// i-th effect is 3 consecutive vec4's: [3*i], [3*i+1], [3*i+2].

                                     // The first vec4 is the Interpolated values,

                                     // second vec4: first float - cache, next 3: Center, the third -  the Region.

//////////////////////////////////////////////////////////////////////////////////////////////

// HELPER FUNCTIONS

//////////////////////////////////////////////////////////////////////////////////////////////

// The trick below is the if-less version of the

//

// t = dx<0.0 ? (u_Bounding.x-v.x) / (u_Bounding.x-ux) : (u_Bounding.x+v.x) / (u_Bounding.x+ux);

// h = dy<0.0 ? (u_Bounding.y-v.y) / (u_Bounding.y-uy) : (u_Bounding.y+v.y) / (u_Bounding.y+uy);

// d = min(t,h);

//

// float d = min(-ps.x/(sign(ps.x)*u_Bounding.x+p.x),-ps.y/(sign(ps.y)*u_Bounding.y+p.y))+1.0;

//

// We still have to avoid division by 0 when p.x = +- u_Bounding.x or p.y = +- u_Bounding.y (i.e

// on the edge of the Object).

// We do that by first multiplying the above 'float d' with sign(denominator1*denominator2)^2.

//

// 2019-01-09: make this 3D. The trick: we want only the EDGES of the cuboid to stay constant.

// the interiors of the Faces move! Thus, we want the MIDDLE of the PS/(sign(PS)*u_Bounding+S) !

//////////////////////////////////////////////////////////////////////////////////////////////

// return degree of the point as defined by the cuboid (u_Bounding.x X u_Bounding.y X u_Bounding.z)

float degree_object(in vec3 S, in vec3 PS)

  {

  vec3 ONE = vec3(1.0,1.0,1.0);

  vec3 A = sign(PS)*u_Bounding + S;

  vec3 signA = sign(A);                      //

  vec3 signA_SQ = signA*signA;               // div = PS/A if A!=0, 0 otherwise.

  vec3 div = signA_SQ*PS/(A-(ONE-signA_SQ)); //

  vec3 ret = sign(u_Bounding)-div;

  float d1= ret.x-ret.y;

  float d2= ret.y-ret.z;

  float d3= ret.x-ret.z;

  if( d1*d2>0.0 ) return ret.y;             //

  if( d1*d3>0.0 ) return ret.z;             // return 1-middle(div.x,div.y,div.z)

  return ret.x;                             // (unless size of object is 0 then 0-middle)

  }

//////////////////////////////////////////////////////////////////////////////////////////////

// Return degree of the point as defined by the Region. Currently only supports spherical regions.

//

// Let 'PS' be the vector from point P (the current vertex) to point S (the center of the effect).

// Let region.xyz be the vector from point S to point O (the center point of the region sphere)

// Let region.w be the radius of the region sphere.

// (This all should work regardless if S is inside or outside of the sphere).

//

// Then, the degree of a point with respect to a given (spherical!) Region is defined by:

//

// If P is outside the sphere, return 0.

// Otherwise, let X be the point where the halfline SP meets the sphere - then return |PX|/|SX|,

// aka the 'degree' of point P.

//

// We solve the triangle OPX.

// We know the lengths |PO|, |OX| and the angle OPX, because cos(OPX) = cos(180-OPS) = -cos(OPS) = -PS*PO/(|PS|*|PO|)

// then from the law of cosines PX^2 + PO^2 - 2*PX*PO*cos(OPX) = OX^2 so PX = -a + sqrt(a^2 + OX^2 - PO^2)

// where a = PS*PO/|PS| but we are really looking for d = |PX|/(|PX|+|PS|) = 1/(1+ (|PS|/|PX|) ) and

// |PX|/|PS| = -b + sqrt(b^2 + (OX^2-PO^2)/PS^2) where b=PS*PO/|PS|^2 which can be computed with only one sqrt.

float degree_region(in vec4 region, in vec3 PS)

  {

  vec3 PO  = PS + region.xyz;

  float D = region.w*region.w-dot(PO,PO);      // D = |OX|^2 - |PO|^2

  if( D<=0.0 ) return 0.0;

  float ps_sq = dot(PS,PS);

  float one_over_ps_sq = 1.0/(ps_sq-(sign(ps_sq)-1.0));  // return 1.0 if ps_sq = 0.0

                                                         // Important: if we want to write

                                                         // b = 1/a if a!=0, b=1 otherwise

                                                         // we need to write that as

                                                         // b = 1 / ( a-(sign(a)-1) )

                                                         // [ and NOT 1 / ( a + 1 - sign(a) ) ]

                                                         // because the latter, if 0<a<2^-24,

                                                         // will suffer from round-off error and in this case

                                                         // a + 1.0 = 1.0 !! so 1 / (a+1-sign(a)) = 1/0 !

  float DOT  = dot(PS,PO)*one_over_ps_sq;

  return 1.0 / (1.0 + 1.0/(sqrt(DOT*DOT+D*one_over_ps_sq)-DOT));

  }

//////////////////////////////////////////////////////////////////////////////////////////////

// return min(degree_object,degree_region). Just like degree_region, currently only supports spheres.

float degree(in vec4 region, in vec3 S, in vec3 PS)

  {

  vec3 PO  = PS + region.xyz;

  float D = region.w*region.w-dot(PO,PO);     // D = |OX|^2 - |PO|^2

  if( D<=0.0 ) return 0.0;

  vec3 A = sign(PS)*u_Bounding + S;

  vec3 signA = sign(A);

  vec3 signA_SQ = signA*signA;

  vec3 div = signA_SQ*PS/(A-(vec3(1.0,1.0,1.0)-signA_SQ));

  vec3 ret = sign(u_Bounding)-div;            // if object is flat, make ret.z 0

  float d1= ret.x-ret.y;

  float d2= ret.y-ret.z;

  float d3= ret.x-ret.z;

  float degree_object;

       if( d1*d2>0.0 ) degree_object= ret.y;  //

  else if( d1*d3>0.0 ) degree_object= ret.z;  // middle of the ret.{x,y,z} triple

  else                 degree_object= ret.x;  //

  float ps_sq = dot(PS,PS);

  float one_over_ps_sq = 1.0/(ps_sq-(sign(ps_sq)-1.0));  // return 1.0 if ps_sq = 0.0

  float DOT  = dot(PS,PO)*one_over_ps_sq;

  float degree_region = 1.0/(1.0 + 1.0/(sqrt(DOT*DOT+D*one_over_ps_sq)-DOT));

  return min(degree_region,degree_object);

  }

#endif  // NUM_VERTEX>0

//////////////////////////////////////////////////////////////////////////////////////////////

void main()

  {

  vec3 v = u_Stretch*a_Position;

  vec3 n = a_Normal;

  v += u_Inflate*u_Stretch*a_Inflate;

#if NUM_VERTEX>0

  int effect=0;

  for(int i=0; i<vNumEffects; i++)

    {

    // ENABLED EFFECTS WILL BE INSERTED HERE

    effect+=3;

    }

#endif

  v_Position      = v;

  v_endPosition   = v + (0.2*u_Stretch.x)*n;

  v_TexCoordinate = a_TexCoordinate;

  v_Normal        = normalize(vec3(u_MVMatrix*vec4(n,0.0)));

  gl_Position     = u_MVPMatrix*vec4(v,1.0);

  }